【ExcelVBA】シングルクォート区切りのdatファイルを作成する

ねぇもりさん、VBAでdatファイル作れるかな？

もり

datファイル?!

datファイル（ダットファイル）とは、拡張子が .dat の「データファイル」です。システムに取り込むデータなどに使われます。

シングルクォート区切りのdatファイル、作ってよ

もり

お、おぅ・・・まかせろ！

エクセルシートのデータから、シングルクォート区切りのdatファイルを作成します。

Contents

SaveAsメソッドでdatファイルは作れない？
Excelシートからdatファイルを作成する
Printメソッドで改行しない方法

SaveAsメソッドでdatファイルは作れない？

ファイル保存といえばSaveAsメソッドですが・・・

SaveAsメソッドのフォーマットに「dat」形式は指定できないようです。

もり

仕方ないね…地道な方法で作るわよ

【方針】

エクセルシートの「各セルの値」にシングルクォートを挟んで連結する
最終列の場合、改行する
※ただし、最終行・最終列の場合は改行しない

こんな感じですね↓

値‘値‘値‘値‘値(改行)
値‘値‘値‘値‘値(改行)
値‘値‘値‘値‘値

Excelシートからdatファイルを作成する

アクティブシートのデータからdatファイルを作成するコードです。2行目以降をファイルに出力します。

※1行目から出力したい場合は、19行目 For r = 2 To lastRow の 2 を 1 に変更してください。

Sub exportDATFile()

    Dim ws As Worksheet
    Set ws = ActiveSheet
    
    Dim lastRow As Long, lastCol As Long
    lastRow = ws.Cells(1, 1).End(xlDown).Row
    lastCol = ws.Cells(1, 1).End(xlToRight).Column
    
    Dim datFile As String
    datFile = ThisWorkbook.Path & "\sample.dat" '拡張子をdatにする
    
    Open datFile For Output As #1
    
    '2行目～最終行をdatファイルに出力する
    Dim r As Long, c As Long
    Dim val As String
    
    For r = 2 To lastRow
    
        For c = 1 To lastCol
        
            val = ws.Cells(r, c).Value
            
            '★ポイント★Printの行末にセミコロン(;)を付与すると改行しない
            
            If c <> lastCol Then '最終列以外の場合
                Print #1, val & "'"; '改行しない
            ElseIf r = lastRow And c = lastCol Then '最終行・最終列の場合
                Print #1, val; '改行しない
            Else
                Print #1, val '改行する
            End If
            
        Next c
    
    Next r
    
    Close #1
    
    MsgBox "datファイルを出力しました"
    
End Sub